WAV 8-bits mono

[hash6iron]

Hi @pschatzmann .

I'm trying to use NumberFormatConverterStreamT<int16_t, uint8_t> nfc(kitStream), to transform line-in signal to 8-bits. Later I'd like to copy this signal to wav file but nothing is recorded. If I remove nfc all is ok but 16-bits.

How Can I record on WAV 8-bits MONO signal from Line-in?
Thanks in advance

[pschatzmann]

I don't see any reason why this should not work!
Did you eventually forgot to call begin on the converter ?

You could try to replace the output with a CsVOutput or a HexDumpOutput to see if you get any data...

[hash6iron]

Maybe I need to configure something to setup WAV at 8-bits or is not necessary?

[hash6iron]

Hi @pschatzmann .

I try all possible but the result always is the same, WAV is empty. This is my sketch. What is wrong?

kitStream is configured for AudioBoard audiokit v2.2 ESP32 A1S and works fine with WAV, MP3 playing and WAV 16 bits recording, but not 8-bit recording. kitStrem uses Line-in for recording and Line-out for sound monitoring.

  auto new_sr = kitStream.defaultConfig(RXTX_MODE);
  new_sr.sample_rate = 44100;

  kitStream.setAudioInfo(new_sr);

  char  file_name[20] = "/test.wav";
  wavfile = SD_MMC.open(file_name, FILE_WRITE);

  EncodedAudioStream encoder(&wavfile, new WAVEncoder()); 

  NumberFormatConverterStream nfc(kitStream);
  nfc.begin(kitStream.audioInfo().bits_per_sample, 8 );

  MultiOutput multi;

  //out for WAV
  multi.add(encoder);
  //out for Line_out
  multi.add(kitStream);
  //from Line_in of kitStream to multiOutput  
  StreamCopy copier(multi,kitStream);
  // sinco
  copier.setSynchAudioInfo(true);

  //audio settings
  auto ecfg = encoder.defaultConfig();
  ecfg.sample_rate = DEFAULT_WAV_SAMPLING_RATE_REC;
  ecfg.bits_per_sample = 16;
  ecfg.channels = 1; // Mono
  copier.begin(multi, nfc);
  encoder.begin(ecfg)
  
  while (!STOP)
  {
      copier.copy();
  }
  
  copier.end();
  encoder.end();
  wavfile.flush();
  wavfile.close();

[pschatzmann]

What did you get when you replaced the File with a HexDumpOutput ?

If you don't get any output, create the most imple test sketch that just tests this functionality w/o any additional complications: then share this test sketch and the log output with log level info!

I can't compile and run your code above, and it does not match with what you initially described...

[pschatzmann]

I was testing with the following sketch and was getting the correct result.

AudioInfo info(8000, 1, 16);
SineWaveGenerator<int16_t> sineWave( 32000);  
GeneratedSoundStream<int16_t> sound( sineWave); 
//CSVOutput<uint8_t> out;
HexDumpOutput out(Serial);
WAVEncoder wav;
EncodedAudioStream encoder(&out, &wav); 
NumberFormatConverterStreamT<int16_t, uint8_t> converter(encoder);
StreamCopy copier(converter, sound);

void setup() {
  Serial.begin(115200);
  AudioToolsLogger.begin(Serial, AudioToolsLogLevel::Info);
  delay(5000);

  // Setup sine wave
  auto cfgs = sineWave.defaultConfig();
  cfgs.copyFrom(info);
  sineWave.begin(info, N_B4);

  converter.begin(info);
  encoder.begin(converter.audioInfoOut());
  out.begin();

  Serial.println("Test started...");
}

void loop() { 
  copier.copy();
}

Log

...
10:26:14.079 -> [I] CodecWAV.h : 589 - is_streamed! because length is 2147418112
10:26:14.111 -> [I] AudioStreamsConverter.h : 373 - begin 16 -> 8 bits
10:26:14.111 -> [I] AudioTypes.h : 126 - out: sample_rate: 8000 / channels: 1 / bits_per_sample: 8
10:26:14.111 -> [I] AudioEncoded.h : 75 - virtual void audio_tools::EncodedAudioOutput::addNotifyAudioChange(audio_tools::AudioInfoSupport&)
10:26:14.111 -> [I] CodecWAV.h : 577 - sample_rate: 8000
10:26:14.143 -> [I] CodecWAV.h : 578 - channels: 1
10:26:14.143 -> [I] CodecWAV.h : 579 - bits_per_sample: 8
10:26:14.143 -> [I] CodecWAV.h : 589 - is_streamed! because length is 4294967295
10:26:14.143 -> Test started...
10:26:14.143 -> [I] CodecWAV.h : 631 - Writing Header
10:26:14.143 -> 52 49 46 46 1C 0 FF 7F  - 57 41 56 45 66 6D 74 20 
10:26:14.143 -> 10 0 0 0 1 0 1 0  - 40 1F 0 0 40 1F 0 0 
10:26:14.143 -> 1 0 8 0 64 61 74 61  - 24 0 FF 7F 7F AE D6 F1 
10:26:14.143 -> FB F3 DA B2 84 54 2B F  - 3 9 21 47 75 A5 CF ED 
10:26:14.174 -> FB F6 E0 BB 8D 5D 33 13  - 4 6 1B 3F 6C 9C C8 E8 
10:26:14.174 -> FA F9 E6 C3 97 67 3A 18  - 5 4 16 37 63 92 C0 E3 
10:26:14.174 -> F8 FA EB CB A0 70 43 1E  - 8 3 11 2F 59 89 B7 DD 
10:26:14.174 -> F5 FB EF D2 A9 7A 4B 24  - B 3 D 28 50 7F AE D6 
10:26:14.174 -> F2 FB F3 D9 B2 83 54 2B  - E 3 9 22 48 76 A6 CF 
...

I committed the following changes:

• log bit size in WAV codec
• accept AudioInfo in NumberFormatConverterStreamT: otherwise you would need to call setAudioInfo(info); begin(); in two steps
• Corrected the NumberFormatConverterStreamT log to report bits instead of bytes

I was double checking the hex dump with Chatgpt

fmt Subchunk ✅ NOW CORRECT FOR 8-BIT!
text
66 6D 74 20 "fmt "
10 00 00 00 Chunk size = 16 bytes
01 00 Audio format = 1 (PCM)
01 00 Channels = 1 (mono)
40 1F 00 00 Sample rate = 8000 Hz ✓
40 1F 00 00 Byte rate = 8000 bytes/sec ✓
01 00 Block align = 1 byte ✓
08 00 Bits per sample = 8 bits ✓

[hash6iron]

Hello @pschatzmann .

Could you please, test NumberFormatConverterStreamT towards WAV decoder when the source is line_in (AudioBoardStream)to convert from.16 bits to 8 bits? I think that there is a bug (I even analyze the library with IA and summarizes that something is wrong, is not compatible with AudioBoardStream)

Thanks in advance.

[pschatzmann]

Just by having a glance at your sketch there are quite a few obvous issus

• You never start multi
• converter is not used
• You obviously did not think about the timing implications of your using of MultiOutput

[hash6iron]

Hi @pschatzmann

Maybe you don't understand me, I have tested AudioBoardStream --> Number conversion --> encoder WAV later than I ensure that AudioBoardStream --> Encoder WAV works, then the problem is with Number Conversion object.

In my last test, I have left out multi, only used WAV encoder as destiny, and LINE-IN as source.

[pschatzmann]

Then provide the minimal full sketch that can reproduce your issue as requested above!

[hash6iron]

Ok.

Do you have an Audiokit board?

[hash6iron]

Hi @pschatzmann

Here attach a minimal sketch.

#include <SD_MMC.h>
#include "AudioTools.h"
#include "AudioTools/AudioLibs/AudioBoardStream.h"
#include "AudioTools/AudioCodecs/CodecWAV.h"

void setup()
{
    AudioBoardStream kitStream(AudioKitEs8388V1);
    AudioInfo info(44100, 1, 16);

    auto ncfg = kitStream.defaultConfig(RXTX_MODE);
    ncfg.sample_rate = 44100;
    ncfg.input_device = ADC_INPUT_LINE2;
    ncfg.output_device = DAC_OUTPUT_ALL;

    kitStream.setAudioInfo(ncfg);

    // Declaration of wav file output
    File wavfile = SD_MMC.open("/test.wav", FILE_WRITE);
    // Converter object    
    NumberFormatConverterStreamT<int16_t, uint8_t> converter(kitStream);
    // WAV encoder
    EncodedAudioStream encoder(&wavfile, new WAVEncoder()); // Encoder WAV PCM
    // Copier
    StreamCopy copier(encoder,converter);
    copier.setSynchAudioInfo(true);

    // Assignations
    converter.setAudioInfo(info);

    // Initializations
    converter.begin();
    encoder.begin(converter.audioInfoOut());
    copier.begin(converter, encoder);
}
 
void loop()
{   
    int tend = 0;
    while (tend < 10000)
    {
        copier.copy();
        tend++;
    }

    copier.end();
    converter.end();
    encoder.end();
}

[pschatzmann]

This was annoying: your example does not even compile:
Here is the corrected version:

#include "AudioTools.h"
#include "AudioTools/AudioLibs/AudioBoardStream.h"
#include <SD_MMC.h>

AudioBoardStream kitStream(AudioKitEs8388V1);
AudioInfo info(44100, 1, 16);
//File wavfile;
HexDumpOutput out;
NumberFormatConverterStreamT<int16_t, uint8_t> converter(kitStream);
EncodedAudioStream encoder(&out, new WAVEncoder());  // Encoder WAV PCM
StreamCopy copier(encoder, converter);

void setup() {
  Serial.begin(115200);
  AudioToolsLogger.begin(Serial, AudioToolsLogLevel::Info);
  delay(10000);
  Serial.println("starting...");

  auto ncfg = kitStream.defaultConfig(RXTX_MODE);
  ncfg.sample_rate = 44100;
  ncfg.input_device = ADC_INPUT_LINE2;
  kitStream.begin(ncfg);

  // Declaration of wav file output
  //wavfile = SD_MMC.open("/test.wav", FILE_WRITE);
  // Converter object
  // WAV encoder
  copier.setSynchAudioInfo(true);

  // Assignations
  converter.setAudioInfo(info);

  // Initializations
  converter.begin(info);
  encoder.begin(converter.audioInfoOut());
  copier.copyN(2);

  //wavfile.close();
}

void loop() {}

With the expected log:

...
16:04:25.308 -> [I] AudioTypes.h : 126 - out: sample_rate: 44100 / channels: 2 / bits_per_sample: 16
16:04:25.308 -> [I] CodecWAV.h : 577 - sample_rate: 44100
16:04:25.308 -> [I] CodecWAV.h : 578 - channels: 1
16:04:25.308 -> [I] CodecWAV.h : 579 - bits_per_sample: 8
16:04:25.308 -> [I] CodecWAV.h : 589 - is_streamed! because length is 2147418112
16:04:25.308 -> [I] AudioEncoded.h : 75 - virtual void audio_tools::EncodedAudioOutput::addNotifyAudioChange(audio_tools::AudioInfoSupport&)
16:04:25.339 -> [I] CodecWAV.h : 577 - sample_rate: 44100
16:04:25.339 -> [I] CodecWAV.h : 578 - channels: 1
16:04:25.339 -> [I] CodecWAV.h : 579 - bits_per_sample: 8
16:04:25.339 -> [I] CodecWAV.h : 589 - is_streamed! because length is 4294967295
16:04:25.339 -> [I] CodecWAV.h : 631 - Writing Header
16:04:25.339 -> 52 49 46 46 1C 0 FF 7F  - 57 41 56 45 66 6D 74 20 
16:04:25.371 -> 10 0 0 0 1 0 1 0  - 44 AC 0 0 44 AC 0 0 
16:04:25.371 -> 1 0 8 0 64 61 74 61  - 24 0 FF 7F 7D 7C 7F 7D 
16:04:25.371 -> 7F 7E 7D 7F 7E 81 7F 7E  - 81 7E 80 81 81 81 81 81 
16:04:25.371 -> 81 81 82 81 81 81 81 81  - 81 81 81 81 80 80 7F 80 
16:04:25.371 -> 7E 7F 7E 7E 7D 7D 7C 7C  - 7B 7B 7A 7A 79 79 78 78 
16:04:25.371 -> 77 77 76 76 75 76 74 75  - 74 74 73 74 73 73 73 73 
16:04:25.371 -> 73 73 72 73 73 73 73 73  - 73 73 74 74 74 74 75 75 
16:04:25.403 -> 76 75 76 76 77 77 78 78  - 79 79 7A 7A 7B 7A 7C 7B 
16:04:25.403 -> 7D 7C 7D 7D 7E 7E 7F 7E  - 80 7F 80 80 81 80 81 81 
16:04:25.403 -> 81 81 82 82 82 82 82 82  - 82 82 82 82 82 82 81 81 
16:04:25.403 -> 80 81 80 80 7F 7F 7E 7E  - 7D 7D 7C 7C 7B 7B 7A 7A 
16:04:25.403 -> 79 79 78 78 77 77 76 77  - 75 76 75 75 74 74 74 74 
16:04:25.403 -> 73 73 73 73 73 73 73 73  - 73 73 73 73 73 73 74 74 
16:04:25.403 -> 75 74 75 75 76 76 77 76  - 77 77 78 78 79 79 7A 7A 
16:04:25.435 -> 7B 7B 7C 7C 7D 7C 7E 7D  - 7E 7E 7F 7F 80 7F 80 80 
...

Your sketch

• was missing the includes
• did not define the necessary global variables (for the objects to be available in the loop)
• did not close the file
• did not open kitStream

ps. Don't forget the set up the logging both with AudioToolsLogger.begin() and in the Tools menu, so you get the errors provided by the IDF

[hash6iron]

Hello @pschatzmann .

I have tried the sketch with your considerations, but only I achieve:

• Record to WAV, nothing.
• Ear a constant low frequency pulse through line_out

Did you test the skecth recording to WAV file?

I'm using MULTI. This is my function in my project (you could not compile but please tell me where do you thinks is the problem) On the other hand, if I not use converter, all works fine and WAV is recorder without problems.

void WavRecording() 
{
  //-----------------------------------------------------------
  //
  // Esta rutina graba en WAV el audio que entra por LINE IN
  //
  //-----------------------------------------------------------
  String wavfilename = wavfile.name();

  unsigned long progress_millis = 0;
  unsigned long progress_millis2 = 0;
  int rectime_s = 0;
  int rectime_m = 0;
  size_t wavfilesize = 0;

  auto new_sr = kitStream.defaultConfig(RXTX_MODE);
  
  // Guardamos la configuracion de sampling rate
  SAMPLING_RATE = new_sr.sample_rate;
  new_sr.sample_rate = DEFAULT_WAV_SAMPLING_RATE_REC;
  kitStream.setAudioInfo(new_sr);

  logln("Starting WAV recording... on file " + wavfilename);

  EncodedAudioStream encoder(&wavfile, new WAVEncoder()); // Encoder WAV PCM

  AudioInfo info(DEFAULT_WAV_SAMPLING_RATE_REC, 1, 16);
  AudioInfo infoStereo(DEFAULT_WAV_SAMPLING_RATE_REC, 2, 16);
  NumberFormatConverterStreamT<int16_t, uint8_t> nfc(kitStream);

   // --- MultiOutput y copier para WAV ---
  MultiOutput multi;
  multi.add(encoder);
  multi.add(kitStream);

  StreamCopy copier;

  // Agregamos las salidas al multiple
  auto ecfg = encoder.defaultConfig();
  
  if (WAV_8BIT_MONO) 
  {
        // Configuracion del convertidor
        multi.setAudioInfo(info);
        multi.begin();

        //
        nfc.setAudioInfo(info);
        nfc.begin(info);

        // Configuramos el copier
        copier.begin(multi, nfc); // WAV: fuente kitStream, destinos encoder y kitStream
        copier.setSynchAudioInfo(true);

        // Inicializamos el encoder
        encoder.begin(nfc.audioInfoOut());
  } 
  else 
  {
        // Configuramos el encoder para 44KHz, 16-bit stereo
        multi.setAudioInfo(infoStereo);
        multi.begin();

        //
        copier.begin(multi, kitStream); // WAV: fuente kitStream, destinos encoder y kitStream
        copier.setSynchAudioInfo(true);

        encoder.begin(infoStereo);
  }

  // Iniciamos el encoder con la configuración de señal
  // Actuamos sobre el amplificador
  kitStream.setPAPower(ACTIVE_AMP && EN_SPEAKER);
  
  // Reset de variables
  STOP = false;
  WAVFILE_PRELOAD = false;
  BTNREC_PRESSED = false;

  // Indicamos
  hmi.writeString("tape.lblFreq.txt=\"" + String(int(ecfg.sample_rate / 1000)) +
                  "KHz\"");
  
  uint32_t samplesWritten = 0;

  while (!STOP && !BTNREC_PRESSED)
  {
        size_t samplesCopied = copier.copy();
        wavfilesize += samplesCopied;
  }

  copier.end();
  encoder.end();
  nfc.end();
  multi.end();

  // Cerramos el fichero WAV
  wavfile.flush();
  wavfile.close();

  WAVFILE_PRELOAD = true;

}

[hash6iron]

Hi again @pschatzmann.

I have test your sketch with file instead hexdump and nothing is recorded. I have test the skech in three differents AudioKit boards, without success.

I'm using the last version of AudioTools.

[hash6iron]

Hi @pschatzmann,

I achieved that 8-bit converter works with WAV, but line_out doesn't work fine (a constant low frecuency noise is earing). At the end for WAV in necessary that inicialization will be as following:

I'm using the last version of AudioTools

NOTE: nfc is converter

    ...
    nfc.setAudioInfo(info);
    nfc.begin(info);

    // Inicializamos el multiple output con la configuración de señal del convertidor
    multi.begin(info);
    // Configuramos el copier
    copier.begin(multi, nfc); // WAV: fuente kitStream, destinos encoder y kitStream
    copier.setSynchAudioInfo(true);
    // IMPORTATNTE: Inicializamos el encoder y kitStream con la configuración de señal del convertidor
    encoder.begin(nfc.audioInfoOut());
    ...

[hash6iron]

Hi @pschatzmann

I continue having problems with audio out when after convert 16 bits WAV to 8-bits WAV on real time, the audio out through line-out (kitStream board) is bad although the WAV is recorded well. This case not occurs when I don't convert from 16-bits to 8-bits with NumberFormatConverterStreamT

Cound you have a look and test it on AudioKit with ES8388 audio codec? I think that there is a bug.
Thanks.

I attach two audio files.

• rec-237373.wav file is a recording from line-in using the 8-bit converter to WAV file.
• line_out.wav file is a recording with my phone of the speaker out on real time when 8-bit converter is working.

rec-237373.wav

line_out.wav

[pschatzmann]

Using ffprobe:

Input #0, wav, from 'rec-237373.wav':
Duration: 00:00:29.12, bitrate: 352 kb/s
Stream #0:0: Audio: pcm_u8 ([1][0][0][0] / 0x0001), 44100 Hz, 1 channels, u8, 352 kb/s

Input #0, wav, from 'line_out.wav':
Metadata:
encoder : Lavf60.16.100
Duration: 00:00:18.60, bitrate: 705 kb/s
Stream #0:0: Audio: pcm_s16le ([1][0][0][0] / 0x0001), 44100 Hz, 1 channels, s16, 705 kb/s

I guess you are writing 8 bit data but pretend that it is 16 bits!

[hash6iron]

Sorry,
but I didn't understand it.

What could be the better lowest lost performance solution to permit 16 bits on I2S and 8 bits for WAV encoder?
Regards.

[pschatzmann]

• I2S supports 16, 24 and 32 bits: all of them need to be signed!
• 8 bit WAV uses unsigned integers!

[E] I2SCodecStream.h : 339 - Unsupported bits: 8

Is just telling you what I told you above: I2S does not support 8 bit data

[hash6iron]

Yes, now I know it but How can I send LINE_IN audio to I2S with 16 bits and WAV file to 8-bits without using two copiers? With two copiers the lost performance is ver big and output audio is very bad.

[pschatzmann]

By defning your processing chain correctly

                          
                         16bit                                8 bit
    16bit                    --- NumberFormatConverterStreamT -> File
I2SStream -copy- MultiOutput -
                             ----------------------------------> I2SStream                       
                         16 bit```

[hash6iron]

Yes I did it.

I have yet problems to understand the audio chain is not easy, mainly in case like this.

Sorry for the insistence, now all works fine. To talk with you, it did help me to continue testing and solve the problem.

Thanks so much.
Regards.

[hash6iron]

At the I achieve to obtain 8-bits on WAV and 16-bits for output without lossing quality.

Here is the code.

void WavRecording() {
  //-----------------------------------------------------------
  //
  // Esta rutina graba en WAV el audio que entra por LINE IN
  //
  //-----------------------------------------------------------
  String wavfilename = wavfile.name();

  unsigned long progress_millis = 0;
  unsigned long progress_millis2 = 0;
  int rectime_s = 0;
  int rectime_m = 0;
  size_t wavfilesize = 0;

  auto new_sr = kitStream.defaultConfig(RXTX_MODE);
  // Guardamos la configuracion de sampling rate
  SAMPLING_RATE = new_sr.sample_rate;
  new_sr.sample_rate = DEFAULT_WAV_SAMPLING_RATE_REC;
  kitStream.setAudioInfo(new_sr);
  // Actuamos sobre el amplificador
  kitStream.setPAPower(ACTIVE_AMP && EN_SPEAKER);  

  logln("Starting WAV recording... on file " + wavfilename);

  AudioInfo info(DEFAULT_WAV_SAMPLING_RATE_REC, 1, 16);
  AudioInfo infoStereo(DEFAULT_WAV_SAMPLING_RATE_REC, 2, 16);
  // Stream de audio del WAV
  EncodedAudioStream encoder(&wavfile, new WAVEncoder()); // Encoder WAV PCM
  // Convertidor 16 a 8 bits
  NumberFormatConverterStreamT<int16_t, uint8_t> nfc;

  // --- MultiOutput y copier para WAV ---
  MultiOutput multi;

  if (WAV_8BIT_MONO)
  {
    multi.add(nfc);
    multi.add(kitStream);
    nfc.setOutput(encoder);
  }
  else
  {
    multi.add(encoder);
    multi.add(kitStream);
  }

  StreamCopy copier;

  // Agregamos las salidas al multiple
  
  if (WAV_8BIT_MONO) 
  {
    // Configuramos el convertidor para 8-bit mono, con la misma frecuencia de muestreo que el encoder
    // Configuracion del convertidor
    nfc.setAudioInfo(info);
    nfc.begin(info);

    // Inicializamos el multiple output con la configuración de señal del convertidor
    //multi.setAudioInfo(info);
    multi.begin(info);
    // Configuramos el copier
    copier.begin(multi, kitStream); // WAV: fuente kitStream, destinos encoder y kitStream
    copier.setSynchAudioInfo(true);
    // IMPORTATNTE: Inicializamos el encoder y kitStream con la configuración de señal del convertidor
    encoder.begin(nfc.audioInfoOut());
  } 
  else 
  {
    // Configuramos el encoder para 44KHz, 16-bit stereo, 2 canales
    multi.setAudioInfo(infoStereo);
    multi.begin();
    // Configuramos el copier
    copier.begin(multi, kitStream); // WAV: fuente kitStream, destinos encoder y kitStream
    copier.setSynchAudioInfo(true);
    // Inicializamos el encoder
    encoder.begin(infoStereo);
  }

  // Reset de variables
  STOP = false; 
  uint32_t samplesWritten = 0;

  //
 while (!STOP && !BTNREC_PRESSED)
 {
    size_t samplesCopied = copier.copy();
    wavfilesize += samplesCopied;
  }

  logln("File has ");
  log(String(wavfilesize / 1024));
  log(" Kbytes");

  logln("Recording finish!");

  copier.end();
  encoder.end();
  nfc.end();
  multi.end();

  // Cerramos el fichero WAV
  wavfile.flush();
  wavfile.close();
}