OCPBUGS-45192: Add e2e test for router service IP connectivity

Author: pacevedom

test/suites/standard1/networking-smoke.robot

@@ -35,6 +35,25 @@ Router Smoke Test
     ...    Delete Hello MicroShift Pod And Service
     ...    Wait For Service Deletion With Timeout
 
+Router Service IP Connectivity
+    [Documentation]    Verify that the router is accessible on all IP addresses
+    ...    assigned to the router-default LoadBalancer service.
+    [Setup]    Run Keywords
+    ...    Create Hello MicroShift Pod
+    ...    Expose Hello MicroShift Service Via Route
+    ...    Restart Router
+
+    @{ips}=    Get Router Service IPs
+    FOR    ${ip}    IN    @{ips}
+        Wait Until Keyword Succeeds    10x    6s
+        ...    Access Hello Microshift Success    ${HTTP_PORT}    ushift_ip=${ip}
+    END
+
+    [Teardown]    Run Keywords
+    ...    Delete Hello MicroShift Route
+    ...    Delete Hello MicroShift Pod And Service
+    ...    Wait For Service Deletion With Timeout
+
 Load Balancer Smoke Test
     [Documentation]    Verify that Load Balancer correctly exposes HTTP service
     Verify Hello MicroShift LB
@@ -57,6 +76,18 @@ Ingress Smoke Test
 
 
 *** Keywords ***
+Get Router Service IPs
+    [Documentation]    Get all IP addresses from the router-default LoadBalancer service
+    ...    in the openshift-ingress namespace.
+    ${output}=    Oc Get JsonPath
+    ...    service
+    ...    openshift-ingress
+    ...    router-default
+    ...    .status.loadBalancer.ingress[*].ip
+    Should Not Be Empty    ${output}    Router service has no LoadBalancer ingress IPs
+    @{ips}=    Split String    ${output}
+    RETURN    @{ips}
+
 Expose Hello MicroShift Service Via Route
     [Documentation]    Expose the "hello microshift" application through the Route
     Oc Expose    pod hello-microshift -n ${NAMESPACE}