OCPBUGS-45192: Add e2e test for router service IP connectivity

Author: pacevedom

test/suites/standard1/networking-smoke.robot

@@ -35,6 +35,25 @@ Router Smoke Test
     ...    Delete Hello MicroShift Pod And Service
     ...    Wait For Service Deletion With Timeout
 
+Router Service IP Connectivity
+    [Documentation]    Verify that the router is accessible on all IP addresses
+    ...    assigned to the router-default LoadBalancer service.
+    [Setup]    Run Keywords
+    ...    Create Hello MicroShift Pod
+    ...    Expose Hello MicroShift Service Via Route
+    ...    Restart Router
+
+    @{ips}=    Get Router Service IPs
+    FOR    ${ip}    IN    @{ips}
+        Wait Until Keyword Succeeds    10x    6s
+        ...    Access Hello MicroShift From Host    ${ip}    ${HTTP_PORT}
+    END
+
+    [Teardown]    Run Keywords
+    ...    Delete Hello MicroShift Route
+    ...    Delete Hello MicroShift Pod And Service
+    ...    Wait For Service Deletion With Timeout
+
 Load Balancer Smoke Test
     [Documentation]    Verify that Load Balancer correctly exposes HTTP service
     Verify Hello MicroShift LB
@@ -57,6 +76,30 @@ Ingress Smoke Test
 
 
 *** Keywords ***
+Get Router Service IPs
+    [Documentation]    Get all IP addresses from the router-default LoadBalancer service
+    ...    in the openshift-ingress namespace.
+    ${output}=    Oc Get JsonPath
+    ...    service
+    ...    openshift-ingress
+    ...    router-default
+    ...    .status.loadBalancer.ingress[*].ip
+    Should Not Be Empty    ${output}    Router service has no LoadBalancer ingress IPs
+    @{ips}=    Split String    ${output}
+    RETURN    @{ips}
+
+Access Hello MicroShift From Host
+    [Documentation]    Access hello-microshift from the MicroShift host via SSH using the given IP.
+    [Arguments]    ${router_ip}    ${port}    ${hostname}=${HOSTNAME}
+    ${ip}=    Add Brackets If Ipv6    ${router_ip}
+    ${stdout}    ${stderr}    ${rc}=    SSHLibrary.Execute Command
+    ...    curl -k -i --connect-to "${hostname}::${ip}:" "http://${hostname}:${port}"
+    ...    sudo=False    return_rc=True    return_stderr=True    return_stdout=True
+    Log Many    ${stdout}    ${stderr}
+    Should Be Equal As Integers    0    ${rc}
+    Should Match Regexp    ${stdout}    HTTP.*200
+    Should Contain    ${stdout}    Hello MicroShift
+
 Expose Hello MicroShift Service Via Route
     [Documentation]    Expose the "hello microshift" application through the Route
     Oc Expose    pod hello-microshift -n ${NAMESPACE}