practical-exercises/flake.nix at master · inet-tub/practical-exercises · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    disko = {
      url = "github:nix-community/disko/latest";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    nixos-facter-modules = {
      url = "github:numtide/nixos-facter-modules";
    };
  };
  outputs = (
    inputs@{
      self,
      nixpkgs,
      ...
    }:
    let
      tools = import ./tools {lib = nixpkgs.lib;};
    in
    {
      nixosModules = tools.setFromDir ./modules;
      nixosConfigurations = builtins.listToAttrs (
        map ( machine: {
          name = machine;
          value = nixpkgs.lib.nixosSystem (
            let
              data = import ./machines/${machine};
            in {
              specialArgs = {
                inherit
                  inputs
                  data
                  tools
                ;
                flake-self = self;
              };
              system = data.system;
              modules = [
                ./machines/${machine}/configuration.nix
                inputs.disko.nixosModules.disko
                inputs.nixos-facter-modules.nixosModules.facter
                { config.facter.reportPath = ./machines/${machine}/facter.json; }
                ./machines/${machine}/disk.nix
                { imports = builtins.attrValues self.nixosModules; }
              ];
            }
          );
        }) (builtins.attrNames (
          nixpkgs.lib.attrsets.filterAttrs (name: type: type == "directory") (builtins.readDir ./machines)
        ))
      );
    }
  );
}